DSAS開発者の部屋

#!/usr/bin/env perl

use strict;
use warnings;
use Carp;

use Readonly;
use UNIVERSAL::require;
use Net::CIDR::MobileJP;
use Array::Diff;
use Pod::Usage;
use YAML;
use Mail::Send;

use Getopt::Long;
use Data::Dumper;
$Data::Dumper::Indent = 1;
$Data::Dumper::Deepcopy = 1;
$Data::Dumper::Sortkeys = 1;
BEGIN {
    my $debug_flag = $ENV{SMART_COMMENTS} || $ENV{SMART_COMMENT} || $ENV{SMART_DEBUG} || $ENV{SC};
    if ($debug_flag) {
        my @p = map { '#'x$_ } ($debug_flag =~ /([345])?s*/g);
        Smart::Comments->use(@p);
    }
}

# name of Net::CIDR::MobileJP::Scraper::Plugin::*
Readonly my @CARRIER => qw(DoCoMo EZweb Vodafone AirHPhone);
Readonly my $STORE_DIR => '/var/state/ktai-cidr';

MAIN: {
    my %opt;
    Getopt::Long::Configure("bundling");
    GetOptions(?%opt,
               'help|h|?') or pod2usage(2);
    pod2usage(2) if exists $opt{'help'};

    for my $carrier (@CARRIER) {
        ### start: $carrier
        my $module = 'Net::CIDR::MobileJP::Scraper::Plugin::' . $carrier;
        unless ($module->use) {
            carp "[SKIP] $module: $@";
            next;
        }
        my $scraper = $module->new;
        my $retry = 3;
        my $result;
        while ($retry-- > 0) {
            $result = $scraper->run;
            ### $result
            last if @{ $result };
            ### retry: $retry
        }

        if (! @{ $result } > 0) {
            carp "[SKIP] cannot retrieve CIDR for $carrier";
            next;
        }

        my $cidr_new = $result;
        my $cidr_old;
        if (-r "${STORE_DIR}/${carrier}.yaml") {
            $cidr_old = YAML::LoadFile("${STORE_DIR}/${carrier}.yaml");
        } else {
            $cidr_old = ['NO DATA'];
        }
        ### old: $cidr_old
        ### new: $cidr_new

        my $diff = Array::Diff->diff( $cidr_old, $cidr_new );

        if ($diff->count > 0) {
            process_diff(carrier => $carrier,
                         url     => $scraper->url,
                         old     => $cidr_old,
                         new     => $cidr_new,
                         diff    => $diff,
                        );
            YAML::DumpFile("${STORE_DIR}/${carrier}.yaml", $cidr_new);
        }

    }

    exit 0;
}

sub process_diff {
    my %param = @_;
    my $carrier = $param{carrier};
    my $url     = $param{url};
    my $old     = $param{old};
    my $new     = $param{new};
    my $diff    = $param{diff};

    my $change;
    push @{ $change->{$carrier} }, { url => $url };
    if (@{ $diff->added }) {
        push @{ $change->{$carrier} }, { added => $diff->added };
    }
    if (@{ $diff->deleted }) {
        push @{ $change->{$carrier} }, { deleted => $diff->deleted };
    }
    push @{ $change->{$carrier} }, { new => $new};
    push @{ $change->{$carrier} }, { old => $old};

    my $change_text = YAML::Dump( $change );
    ### change: $change_text

    # send_diff($carrier, $change_text);
}

sub send_diff {
    my ($carrier, $body) = @_;
    ### send_diff
    my $mail = Mail::Send->new;
    $mail->subject("[NOTIFY] $carrier GW IP address was updated");

    $mail->set('Mime-Version', '1.0');
    $mail->set('Content-Type', 'text/plain; charset=iso-2022-jp');
    $mail->set('Content-Transfer-Encoding', '7bit');
    $mail->set('X-Mailer', $0);

    $ENV{QMAILSUSER} = 'ktai-cidr-scraper';
    $ENV{QMAILSHOST} = 'example.org';
    $mail->set('From', join('@', @ENV{qw(QMAILSUSER QMAILSHOST)}));

    $mail->to('notifyme@example.org');

    my $fh = $mail->open;
    print {$fh} $body;
    $fh->close;
}

__END__